Spice model varistorja

(SLO, ENG)

 Kazalo:

Uvod
Cilji in naloge
Spice model varistorja
Testno vezje

Analize
1.Analiza napetosti, toka in energije varistorja zaradi udarca strele
Rezultati 1. analize
2. Analiza vezja pri omrežni napetosti in streli
Rezultati 2. analize
3.Analiza vezja ob spreminjanju Rd
Rezultati 3. analize
4.Analiza vezja z dodano induktivnostjo
Rezultati 4. analize

Povzetek

Home


1.UVOD:

   Varistorji (VDR- Voltage Dependent Resistors) so upori z veliko nelinearno odvisnostjo upornosti od napetosti. Pri prekoračitvi nazivne napetosti varistorja upornost elementa drastično pade, česar posledica je hitro naraščanje toka. Tako se nam varistor kaže kot idealen element za zaščito pred prenapetostmi.
    Osnovni materiali so keramike:  cinkov oksid ZnO in silicijev karbid SiC. V večini se uporablja ZnO zaradi večje nelinearnosti, čeprav pri nekaterih proizvajalcih srečamo tudi SiC.
    Z dodatki določenih primesi dobi osnovna keramika po sintranju lastnosti polprevodniške keramike N ali P tipa, podobno kot polprevodniki. Sintranje mora potekati v kisikovi atmosferi, da dobimo varistorski efekt. Kisikovi atomi med sintranjem prodrejo v zrnato strukturo keramike in med zrni nastanejo visokoohmske bariere. Pri nizkih napetostih (električnih poljih) ima material visoko upornost.


Pri višjih napetostih pa pride do tuneliranja elektronov skozi bariere. Zaradi tega toka se bariere lokalno segrejejo in njihova upornost se naglo zmanjša (NTC - Negativni Temperaturni Koeficient).

    Nelinearno U-I karakteristiko varistorja lahko zapišemo:

                                        U(I)=C*Iß
                                    ali I(U)=K*Ua

    Karakteristika velja tudi za negativne napetosti in je liha. Zato mora biti a liho celo število.

Nazaj na kazalo


  2.CILJI IN NALOGE:

Cilj naloge je zgraditi spice model varistorja, ugotoviti njegove glavne lastnosti, analizirati njegovo obnašanje v modelu, ki vključuje: električno omrežje, prenapetostni sunek, vezje za zaščito. Gradnja modela naj bazira na izmerjenih karakteristikah konkretnega elementa. Izbran element naj bo dosegljiv na tržišču in naj bo dovolj cenen. Pri modelu se morajo vključiti tudi energetske razmere na varistorju, ki naj bodo pokazatelj vzdržljivosti elementa. Naloga naj bi bila mišljena kot pomoč pri razumevanju glavnih dejavnikov, ki vplivajo na nivo zaščite pred prenapetostnimi sunki  z varistorji. Hkrati naj bi načrtovalec vezja za zaščito v tej nalogi poiskal glavne smernice za načrtovanje vezij te vrste.

3.SPICE MODEL VARISTORJA:

    Osnovni podatki varistorjev po proizvajalcu KEKO VARICON:

Vrms........maksimalna efektivna sinusna napetost, na katero je lahko varistor trajno priključen pri 25°C
Vdc..........maksimalna enosmerna napetost, na katero je lahko varistor trajno priključen pri 25°C Vn............nazivna napetost varistorja ( pri toku 1mA)
Vc............maksimalna napetost na varistorju, pri standardnem tokovem impulzu amplitude Ic
Ic.............amplituda standardnega tokovnega impulza 8/20ms, ki je 1/10 Imax
Wmax......energija, ki jo lahko varistor absorbira brez uničenja pri enkratnem 10/1000ms impulzu in normalnem delovanju (varistor je priključen na izmenično napetost Vrms)
Pmax.......povprečna moč vlaka impulzov, ki jih lahko varistor prenese brez uničenja v določenem času
Imax........maksimalna amplituda tokovnega impulza 8/20ms, ki ga varistor prenese brez uničenja C.............kapaciteta med priključkoma varistorja merjena pri 1kHz Spice model je podan na primeru varistorja proizvajalca KEKO VARICON, tip CV230 K20.    

  Vrms  Vdc  Vn  Vc  Ic  Wmax  P  Imax  C 
CV230K20  230V  300V  360V  595V  100A   168J  1W  6500A  1400pF 

 Zaradi lažjega zapisa uporabimo naslednjo formulo karakteristike:  I(U)=(K×U)a

Iz podane tabele vzamemo dve karakteristični točki (Vn,1mA) in (Vc,Ic), iz katerih izračunamo oba parametra K in a.

U1=360V, I1=1mA
U2=595V, I2=100A

a=ln(I2/I1)/ln(U2/U1)=ln(100/0.001)/ln(595/360)=22.91­=23

K=(aÖI)/U=(23Ö0.001)/360=0.002057

Parameter a je potrebno zaokrožiti na prvo celo višjo liho vrednost, zaradi lihega značaja karakteristike varistorja.

    Iz grafično podane karakteristike varistorja v log merilu vidimo, da se začne karakteristika pri velikih tokovih oddaljevati od namišljene idealne premice navzgor, kar pomeni padec napetosti na notranji upornosti varistorja, ki je vsota upornosti priključnih žičk in keramične tabletke same.

Odčitamo:
I=5000A   Uodč=840V

Izračunamo kakšna bi bila napetost pri idealnem varistorju:
Uizr=(aÖI)/K=(23Ö5000)/0.002057=740V

Razlika med Uodč in Uizr je padec napetosti na notranji upornosti:
DU=Uodč -Uizr=136V

Rvar=DU/I=136V/5000A=0.0272W








Rnv1.gif
 Osnovni spice model varistorja je torej nelinearen krmiljen
tokov vir in notranja upornost Rvar.
 
 
 

Bvar 7 0 I=(0.002057*v(7))^23
Rvar 6 7 0.0272
 
 
 
 
 
 
 


Zanima nas tudi energija, ki jo varistor absorbira:

Rnv3.gif
Ker za napetost na kondenzatorju velja:

lahko formuli za energijo priredimo ekvivalentno vezje:

Ben 0 100 I=v(6)*i(Vvar)
Cen 100 0 1
Ren 100 0 100Meg
 
 Tok krmiljenega vira je ekvivalenten moči na varistorju, napetost na kondenzatorju pa je integral tega toka (moči). To je energija, ki jo absorbira varistor. Ren=100MW moramo dodati, da matrika v spice-u ni singularna.


Naslednji program izriše statično I(U) karakteristiko varistorja preko DC analize s spreminjanjem enosmernega vira Vin.

Test.gif
karakteristika varistorja
Bvar 7 0 I=(0.002057*V(7))^23
Rvar 6 7 0.0272

*Tok skozi varistor
vvar    5 6 dc 0

*vzbujanje
vin 5 0 dc 1000V

.control
dc vin -1000 1000 5
plot i(vvar)
.endc

.end
 
  Nazaj na kazalo


4.TESTNO VEZJE:

Rnv2.gif
Vezje je sestavljeno iz:

Na voljo imamo dva modela napetostnega impulza strele. Prvi velja za golo visečo žico, drugi pa za izolirano žico energetske napeljave. Tadva modela sta rezultat merjenj na energetski napeljavi. Pri modelu varistorja imamo dodan napetostni vir Vvar = 0V, preko katerega merimo tok skozi varistor.




Nazaj na kazalo


5.ANALIZE:
 
Pri analizah si bomo postopoma gradili vezje za zaščito pred strelo in ugotavljali, kateri so glavni dejavniki, ki vplivajo na kakovost zaščite. Pri vseh analizah je testni impulz strele za golo visečo žico (2100V). Vsakdo si analize lahko sam ponovi z drugim testnim impulzom. Proizvajalci varistorjev testirajo svoje produkte z standardnim testnim impulzom 8/20 ms in z 10/1000 ms, in na podlagi teh testov določijo maksimalne vrednosti toka, energije in moči, ki jih varistor lahko prenese. Vendar so tudi naše analize dovolj objektivne, saj se energija računa neposredno po definiciji in velja za vsak testni impulz.
    Pri prvi analizi  bomo varistor priključili na strelo in smiselno v serijo dodali še neko upornost  Rd, ki pomeni koncentrirano upornost vsega, kar je med vtičnico in varistorjem. Kot izhodno napetost bomo poimenovali napetost na varistorju V(5), vhodna napetost bo pa napetost v vtičnici, se pravi v(3). Ogledali si bomo napetost in tok impulza na varistorju ter energijo, ki jo varistor v tistem trenutku absorbira.
    V drugi analizi bomo k vzbujanju dodali sinusno napetost 230V, impulz strele premaknili za 5ms in si ogledali, kako se varistor tedaj obnaša.
    Pri tretji nanalizi si bomo ogledali odvisnost izhodne napetosti pri udarcu strele od velikosti upornosti Rd. Videli bomo, kje so postavljene meje za našo zaščito.
    V četrti analizi bomo v serijo z Rd dodali tuljavo Ld, ki lahko pomeni induktivnost omrežja samega ali pa dodano tuljavo kot element, ki omejuje hitre spremembe toka.

Nazaj na kazalo


1.Analiza napetosti, toka in energije varistorja zaradi udarca strele:

Rnv5.gif
Analiza1
Bvar    7  0 I=(0.002057*v(7))^23
Rvar    6  7 0.0272
Vvar    5  6 dc 0
VSTRELA 2  0 EXP 0V 2100V 0m 1.5US 4US 70US
*VSTRELA 2  0 EXP 0V 1050V 0m 2.2US 10US 350US
RSTRELA 3  2 0.13
Rd      3  5 1
*energijski model
Ben    0 100 i=v(6)*i(Vvar)
Cen    100 0 1
Ren    100 0 100Meg
.control
tran 0.2u 250u 0 0.2u
plot v(3) v(5) i(Vvar)
plot v(100)
.endc
.end
Nazaj na kazalo


Rezultati 1. analize:

Analiza1.gif
Na vhodu vezja (v(3)) je amplituda napetostnega impulza 1850V, medtem ko je na napetost varistorju v(5) le še 690V. Maksimalni tok skozi varistor i(Vvar) je takrat 1160A!! Vendar se moramo zavedati, da so ti napetostni impulzi izredno kratki (vse skupaj traja cca 200us). Razumljiv je podatek, da je energija, ki jo varistor absorbira, le 30.5J (končna napetost na v(100)). Torej se varistor ne uniči. Preostala energija se porabi na upornosti Rd.    Če ta upornost predstavlja varovalko (230V/500mA), potem  je jasno, da ta varovalka takoj pregori.







Nazaj na kazalo


2. Analiza vezja pri omrežni napetosti in streli:
Rnv4.gif
Analiza2
Bvar    7  0 I=(0.002057*v(7))^23
Rvar    6  7 0.0272
Vvar    5  6 dc 0
Vin     1  0 dc 0 sin 0 311V 50Hz
VSTRELA 2  1 EXP 0V 2100V 5m 1.5US 5004US 70US
*VSTRELA 2  1 EXP 0V 1050V 5m 2.2US 5010US 350US
RSTRELA 3  2 0.13
Rd      3  5 1
*energijski model
Ben    0 100 i=v(6)*i(Vvar)
Cen    100 0 1
Ren    100 0 100Meg
.control
tran 10u 20m 0 10u
plot v(3) v(5)
plot v(100)
.endc
.end
Nazaj na kazalo


Rezultati 2. analize:

Analiza21.gif
Slika kaže tok skozi varistor pri priključeni omrežni napetosti brez strele. Vidi se, kako nelinearna je I(U) karakteristika varistorja, saj je tok skozenj zelo popačen. Vendar je v globalnem vrednost toka zanemarljiva, saj je izbran varistor z podatkom Vrms=230V in Vn=360V. Torej varistor ob trajni obremenitvi z sinusno napetostjo 230V ne bi smel prevajati. To se lepo vidi iz grafa, saj je maksimalna vrednost toka 35mA.
 
 









Analiza2.gif
Pri tej analizi smo vključili še omrežno napetost in impulz prestavili na vrh prvega vala (zakasnjen za 5ms), kar nam predstavlja najslabši možni primer. Amplituda impulza na vhodu  je sedaj 2150V, kar je očitno za 310V več kot prej. Vendar amplituda impulza 705V na varistorju ni bistveno večja. Vendar sta zato tokovna špica 1420A in energija 51J, ki jo impulz absorbira precej večji.
 











Nazaj na kazalo


 3.Analiza vezja ob spreminjanju Rd:
Pri tej analizi spreminjamo upor Rd s pomočjo napetostno krmiljenega tokovega vira Brd in z dc analizo analiziramo izhodno napetost pri 311V in 2100V+311V na vhodu. Na izhodu imamo breme Rb=500W.
Analiza3
Bvar    7  0 I=(0.002057*v(7))^23
Rvar    6  7 0.0272
Vvar    5  6 dc 0
Vin     2  0 dc 2100
RSTRELA 3  2 0.13
Rb      5  0 500
*napetostno krmiljeni upor Rd
Brd      3  5 I=(V(3)-V(5))/V(101)
Vr 101 0 1
Rr 101 0 1Meg
.control
*analiza izhodne napetosti v odvisnosti
*od Rd pri 311V in pri 2100V+311V
dc  vr 0.001 100  1 vin 311 2411 2100
.endc
.end
Nazaj na kazalo


Rezultati 3 analize:
Analiza3.gif

Upor Rd se spreminja od 1W do 1kW. Vidimo, da se na začetku pri visoki vhodni napetosti (strela) sprememba upornosti Rd na izhodni napetosti zelo pozna, nato pa ne več tako (zgornja karakteristika).
Hitro pa lahko opazimo, da je določitev te upornosti odvisna od načrtovane bremenske upornosti. To je pomembno za normalno obratovanje pri omrežni napetosti, da ne pride do prevelikega padca napetosti na Rd in s tem do premajhne napetosti na bremenu. To nam kaže spodnja karakteristika za breme  500W.
Zaključimo lahko, da nima smisla dodajati Rd večji od nekaj ohmov. Navadna (200mA/230V) varovalka ima že upornost 1W.





Nazaj na kazalo


4.Analiza vezja z dodano induktivnostjo:
Samo po sebi se rojeva vprašanje, zakaj ne bi dodali v serijo še induktivnost, ki bi blažila napetostne sunke. Da bo analiza popolnejša, k modelu varistorja vključimo še njegovo kapacitivnost.
 

Rnv2.gif
Analiza4
Bvar    7  0 I=(0.002057*v(7))^23
Rvar    6  7 0.0272
Vvar    5  6 dc 0
Cvar  6  0 1400p
Vin     1  0 dc 0 sin 0 311V 50Hz
VSTRELA 2  1 EXP 0V 2100V 5m 1.5US 5004US 70US
*VSTRELA 2  1 EXP 0V 1050V 5m 2.2US 5010US 350US
RSTRELA 3  2 0.13
Rd      3  4 1
Ld 4  5 200u
*energijski model
Ben    0 100 i=v(6)*i(Vvar)
Cen    100 0 1
Ren    100 0 100Meg
.control
tran 10u 20m 0 10u
plot v(3) v(5) i(Vvar)
plot v(100)
.endc
.end

Nazaj na kazalo


Rezultati 4. analize
Analiza4.gif

Opazimo, da tuljava zares zaduši impulz, saj je le-ta na izhodu nižji (631V, prej je bil 705V) in ga časovno raztegne. Tokovni impulz skozi varistor se zaradi induktivnosti bistveno zmanjša (le 301A, prej je bil 1420A), ker je pa precej pomembno, saj lahko potem tako vezje prenese višje napetosti impulzov za enako tokovno obremenitev varistorja. Pomembna je seveda energija, ki jo varistor absorbira. Ta je v tem primeru nekoliko manjša (33J, prej je bila 51J), vendar ta razlika ni tako velika, ker je napetostni impulz na varistorju daljši!
 








Analiza41.gif Če si diagram povečamo, opazimo da se v napetosti na varistorju, ko impulz preide pojavi dušeno nihanje. To je posledica nakopičene energije v dodani induktivnosti Ld. Ta energija se potem pretaka v nihajnem krogu, ki ga predstavljata Ld in Cvar in se počasi porablja na upornostih. Tako velika amplituda nihanja na začetku pa je posledica velikega povečanja upornosti varistorja, skozi katerega v tistem trenutku še vstraja nek tok, ki ga vsiljuje induktivost.
    Dodana tuljava torej povzroča motnje, poleg tega pa mora biti njena induktivnost precej velika, da pride do učinka. Če že je, mora biti zračna, brez jedra.









Nazaj na kazalo


6.POVZETEK:
 
Vse, kar smo do sedaj delali, je bilo takorekoč samo sebi v namen, saj nismo ničesar ščitili. Vendar smo pri prvi analizi ugotovili, če je v vezju varovalka, potem ta takoj pregori. Vendar ta "takoj" ni čisto takoj, saj poznamo več vrst varovalk. Vendar nobena ni tako hitra, da bi pregorela v parih ms. V resnici varovalka pregori šele takrat, ko je strela že zdavnaj mimo. Ker ob udarcu strele ponavadi ni samo enega impulza (do sedaj smo testirali  varistor le na en impulz), temveč se zaradi odbojev na linijah pojavi cel vlak odbitih impulzov, lahko vidimo, da nam tista varovalka začne koristiti, saj varistor lahko zdrži (po proizvajalcu) le določeno povprečno moč tega vlaka impulzov.
    V naše analize tudi nismo vključili nobene naprave, ki naj bi jo varistor ščitil. Izkaže se, da breme ne vpliva bistveno na delovanje našega vezja, če je upornost Rd v primerjavi za ekvivalentno upornostjo bremenba Rb dovolj majhna, kar se vidi iz tretje analize.
 

Sedaj pa še nekaj o tem, kako izbrati varistor za določeno aplikacijo.

1.Normalno obratovanje:
   Vn, nazivna napetost varistorja (pri toku 1mA). Tam kjer začne varistor ščititi. Vse napetosti v normalnem obratovanju morajo biti nižje.
    Vrms in Vdc  izberi maksimalno ali prvo višjo od največjih napetostih pri normalnem obratovanju.

2.Absorbirana energija pri pričakovanih tranzientnih pojavih (ščitenje):

    Energijo lahko izračunamo iz aproksimacijske formule, ki nekemu tokovnemu impulzu aproksimiramo pravokotni impulz.

                    E=K*Ip*Vc*T

K je konstanta in velja: K=1 za pravokotni impulz, K=1.4 za 8/20 ms in 10/1000 ms standardni testni impulz. Ip je amplituda tokovne špice, Vc je napetost na varistorju, T je širina impulza.  

Standardni tokovni impulz 8/20us

3.Maksimalna tranzientna napetost, ki jo vezje, ki ga ščitimo lahko prenese.
    Iz I(U) krivulje odčitamo napetost (clamping voltage) pri toku pričakovanega tokovnega impulza. Izbrani varistor naj bi imel to napetost enako ali nižjo.

4.Imax, maxsimalni trenutni tok, ki ga varistor lahko prenese naj bo večji od maksimalne tokovne špice, ki jo pričakujemo v vezju.

5. Iz diagrama, ki prikazuje tok impulza v odvisnosti od časa trajanja impulza

lahko določimo primeren varistor za našo aplikacijo. Energija, ki jo varistor lahko absorbira brez uničenja je poleg amplitude impulza zelo dovisna od časa trajanja impulza in števila impulzov, ki se ponovijo v enem paketu v razmaku tr.

6.Disipacija moči na varistorju in odvajanje toplote pride do izraza pri stalno se ponavljajočih impulzih, katerih energijo naj varistor absorbira. Če varistor v času pavze med dvema sosednjima impulzoma ne more odvesti dovolj toplote, potem se bo čez nekaj časa uničil.
Varistorji lahko odvajajo relativno malo toplote, zato niso preveč primerni za take režime delovanja.






Nazaj na kazalo


Vse analize so bile narejene na programu Spice Opus, ki pozna tekstovne datoteke *.cir v katerih se mu opiše vezje. Celoten opis programa je v knjigi Tadej Tuma: Analiza vezij s programom SPICE3 založbe FE.
Vse tekstovne datoteke se lahko direktno skopirajo, shranijo v datoteko *.cir in preizkusijo v spice-u.
 
Za vse pripombe v zvezi s programom Spice3, vašimi rezultati, novimi odkritji in morebitnimi mojimi napakimi mi pišite na naslov: Marko.Jankovec@fe.uni-lj.si

Nazaj na kazalo


Literatura:
 


Zahvala dr. Tadeju Tumi za mentorstvo in pomoč in mag. Andreju Levsteku za izčrpne podatke in pomoč.


Še nekaj naslovov proizvajalcev varistorjev:
 
 KEKO VARICON d.o.o.
Grajski trg 15
8360 ŽUŽEMBERK
SLOVENIJA

TEL:                       07 308 70 71
                              07 308 76 71
   
                                  07 302 26 33
FAX:                      07 308 76 34


ISKRA VARISTOR, d.o.o
Stegne 35
1000 LJUBLJANA
SLOVENIJA

Tel:     01 551 15 98
           01 559 11 41
           01 559 92 78
Fax:    01 507 65 67



C.CONRADTY NÜRNBERG GmbH & Co.KG
8500 Nürnberg 1
Postfach 17 52
DEUTCHLAND
Tel: (09 11) 54 88 1
Fax:(09 11) 54 88 211


SAS (SINO-AMERICAN SILICON PRODUCTS INC.)
8, Industrial East Road Sec. 2
Science Based Industrial Park
HSINCHU, TAIWAN, R.O.C.
Tel: 886-3-5772233

E-Mail : Saspi@shts.seed.net.tw

 


Avtor: Marko Jankovec

E-Mail:Marko.Jankovec@fe.uni-lj.si
email.gif (15902 bytes)

Nazaj na kazalo

Home